Difference between revisions of "Copy console GROMs for HSGPL"

From Ninerpedia
Jump to navigation Jump to search
Line 10: Line 10:
  *************************************
  *************************************
  *
  *
  *  HGPLNEW: FLASHES THE HSGPL GROM
  *  CPGROM:   FLASHES THE HSGPL GROM
  *            0-2 FROM THE BACKUP
  *            0-2 FROM THE BACKUP
  *
  *

Revision as of 12:05, 21 August 2015

This file is also available in TIFILES format. You can import that file to a disk image on the PC using TIImageTool or on the TI using a terminal emulator program with XModem transfer (e.g. TELCO).

Downloads

Listing

*************************************
*
*  CPGROM:   FLASHES THE HSGPL GROM
*            0-2 FROM THE BACKUP
*
*            USES THE MODIFIED GROM0
*
*      MICHAEL ZAPF, JUNE 2010
*
***
       DEF  START

START  LI   R12,>1B00
       SBO  0
       SBO  9
       SBO  10
       CLR  R0
       LI   R2,>2000
       LI   R1,>A000
       BL   @COPY
       LI   R1,>C000
       LI   R0,>2000
       BL   @COPY
       LI   R1,>E000
       LI   R0,>4000
       BL   @COPY
       SBZ  10
       SBZ  9
       SBZ  0
       BLWP @>0000
 
COPY   MOV  R11,R9
       MOVB R1,@>9C02
       SWPB R1
       MOVB R1,@>9C02
       SWPB R1
       MOV  R2,R3
       LI   R6,>C000
 
* COPY INTO RAM
LOOP   MOVB @>9840,*R6+
       DEC  R3
       JNE  LOOP
       MOV  R2,R3
 
       LI   R6,>C000
LOOP1  LI   R7,256
       BL   @SDPEA
       MOVB R0,@>9C02
       SWPB R0
       MOVB R0,@>9C02
       SWPB R0
 
LOOP2  MOVB *R6+,@>9C00
       DEC  R3
       DEC  R7
       JNE  LOOP2
       AI   R0,256
 
       LI   R8,2000
WAIT   DEC  R8
       JNE  WAIT
       MOV  R3,R3
       JNE  LOOP1
 
       B    *R9
 
SDPEA  MOV  R11,R10
       BL   @CFI
       DATA >5555,>AA00
       BL   @CFI
       DATA >2AAA,>5500
       BL   @CFI
       DATA >5555,>A000
       B    *R10
 
* DO THE CFI DANCE!
 
CFI    MOV  *R11+,R4
       MOV  *R11+,R5
       MOVB R4,@>9C02
       SWPB R4
       MOVB R4,@>9C02
       NOP
       MOVB R5,@>9C00
       RT
  
       END  START